2015/09/18

チリ津波で観測された津波高をGnuplotで書いてみた(2)

ちょいちょい修正したので書き直し.その1の続きです.

set zrange [0:5]
set xrange [-180:-20]
set yrange [-65:45]
set ticslevel 0

# 任意の場所に任意の文字(ここでは時刻)を表示
set label '     1416 UTC THU SEP 17 2015' at -180,45,5

set grid

set xlabel 'longitude [^o]'
set ylabel 'latitude [^o]'
set zlabel 'Height [m]' rotate by 90

set view ,330

# unset border
# mxticsの数字は,xticsの間にいくつ点をうつかという意味(間隔ではない)
set xtics 30 out
set mxtics 3
set ytics 30 out
set mytics 3
set ztics border

h1(x)=(x<1)? x:0    # 1mより低い場合を抽出
h3(x)=(x<3)? x:0    # 3mより低い場合を抽出

set term png enh font "Times,18" size 720,720
set output "obs18.png"

./obs.pl obs18.dat はデータ整形スクリプトで lon lat height の数字を出力
splot   "world_10m.txt"        u 1:2:(0)       w lines   lt -1 lw 0 notitle \
, "< ./obs.pl obs18.dat" u 1:2:3         w impulse lt  7 lw 3 t  '3m<=' \
, ""                     u 1:2:(h3($3)) w impulse lt  4 lw 3 t '<3m    ' \
, ""                     u 1:2:(h1($3)) w impulse lt  6 lw 3 t '<1m    '

unset output


これを
% convert -delay 100 obs*.png obs.gif
でgifアニメーション化
(東経と西経を別々に作成してmontageで連結しています)